


**Print custom Handling Unit label form using PPF framework in SAP EWM**


Print the custom handling unit label using transaction code: /N/SCWM/MON








Spool request generated



Form preview generated:



Technical details:

Custom action definition details:

Transaction code: SPPFCADM

Application: /SCWM/WME

Action Profile: /SCWM/HU

Action Definition: ZHU\_LABEL

BADI Definition: EXEC\_METHODCALL\_PPF

BADI Implementation: ZEWM\_EI\_HU\_LABEL

Method: EXECUTE


Adobe form: ZEWM\_AF\_HU\_LABEL

Adobe form Interface: ZEWM\_AFI\_HU\_LABEL

**Code in above BADI implementation**

  METHOD if\_ex\_exec\_methodcall\_ppf~execute.  
\*------------------------------------------------------------------------------------------  
\*   This method check for HU identification id and pass it to generate the custom HU lable  
\*   Form : ZEWM\_AF\_HU\_LABEL  
\*------------------------------------------------------------------------------------------  
  
    DATA:lv\_error            TYPE string,  
         lv\_huidentification TYPE /scwm/de\_huident,  
         lv\_warehouse\_no     TYPE /scwm/lgnum,  
         lv\_function\_name    TYPE rs38l\_fnam,  
         lt\_hu\_header        TYPE /scwm/tt\_huhdr\_int,  
         ls\_output\_params    TYPE sfpoutputparams,  
         ls\_formoutput       TYPE fpformoutput,  
         lo\_ao\_hu            TYPE REF TO /scwm/cl\_hu\_ppf,  
         lt\_shp\_lable        TYPE /scwm/tt\_shplabel,  
         lt\_hu\_details       TYPE /scwm/tt\_wo\_info,  
         lv\_print\_param      TYPE /scwm/s\_print,  
         lt\_hu\_hierarchy     TYPE /scwm/tt\_hu\_print\_tree,  
         lt\_hu\_hazard\_mat    TYPE /scwm/t\_hu\_hazard\_mat,  
         lt\_material\_items   TYPE /scwm/tt\_hu\_material,  
         lt\_ser\_labels       TYPE /scwm/tt\_ser\_label,  
         ls\_fp\_docparams     TYPE sfpdocparams.  
  
    IF io\_appl\_object IS BOUND.  
  
\*Get reference to object -> /scwm/cl\_hu\_ppf  
      lo\_ao\_hu ?= io\_appl\_object.  
  
      IF lo\_ao\_hu IS BOUND.  
  
        TRY.  
\*Get HU identification id  
            lv\_huidentification = lo\_ao\_hu->get\_huident( ).  
  
\*Get warehouse number  
            lv\_warehouse\_no = lo\_ao\_hu->get\_lgnum( ).  
  
            IF lv\_huidentification IS NOT INITIAL.  
  
              TRY.  
\*Get function name  
                  CALL FUNCTION 'FP\_FUNCTION\_MODULE\_NAME'  
                    EXPORTING  
                      i\_name     = 'ZEWM\_AF\_HU\_LABEL'  
                    IMPORTING  
                      e\_funcname = lv\_function\_name.  
  
                  IF lv\_function\_name IS NOT INITIAL.  
  
                    ls\_output\_params-reqnew   = abap\_true.  
                    ls\_output\_params-preview  = ' '.  
                    ls\_output\_params-nodialog = abap\_true.  
                    ls\_output\_params-device   = 'PRINTER'.  
                    ls\_output\_params-dest     = 'LP01'.  
  
\*Job open  
                    CALL FUNCTION 'FP\_JOB\_OPEN'  
                      CHANGING  
                        ie\_outputparams = ls\_output\_params  
                      EXCEPTIONS  
                        cancel          = 1  
                        usage\_error     = 2  
                        system\_error    = 3  
                        internal\_error  = 4  
                        OTHERS          = 5.  
                    IF sy-subrc NE 0.  
                      rp\_status =  '2'.  
                      RETURN.  
                    ENDIF.  
  
                    APPEND INITIAL LINE TO lt\_hu\_header ASSIGNING FIELD-SYMBOL(<lfs\_hu\_header>).  
                    IF <lfs\_hu\_header> IS ASSIGNED.  
                      <lfs\_hu\_header>-huident = lv\_huidentification.  
                      <lfs\_hu\_header>-lgnum   = lv\_warehouse\_no.  
                    ENDIF.  
  
\*Call adobe form  
                    CALL FUNCTION lv\_function\_name  
                      EXPORTING  
                        /1bcdwb/docparams  = ls\_fp\_docparams  
                        hu\_details         = lt\_hu\_details  
                        shp\_label          = lt\_shp\_lable  
                        hu\_header          = lt\_hu\_header  
                        print\_param        = lv\_print\_param  
                        hu\_hierarchy       = lt\_hu\_hierarchy  
                        it\_hu\_hazard\_mat   = lt\_hu\_hazard\_mat  
                        material\_items     = lt\_material\_items  
                        it\_ser\_labels      = lt\_ser\_labels  
                      IMPORTING  
                        /1bcdwb/formoutput = ls\_formoutput  
                      EXCEPTIONS  
                        usage\_error        = 1  
                        system\_error       = 2  
                        internal\_error     = 3  
                        OTHERS             = 4.  
                    IF sy-subrc <> 0.  
                      rp\_status =  '2'.  
                      RETURN.  
                    ENDIF.  
  
\*Job close  
                    CALL FUNCTION 'FP\_JOB\_CLOSE'  
                      EXCEPTIONS  
                        usage\_error    = 1  
                        system\_error   = 2  
                        internal\_error = 3  
                        OTHERS         = 4.  
                    IF sy-subrc <> 0.  
                      rp\_status =  '2'.  
                      RETURN.  
                    ELSE.  
                      rp\_status = '1'.  
                    ENDIF.  
  
                  ENDIF.  
  
                CATCH cx\_fp\_api INTO DATA(lo\_fp\_api).  
                  rp\_status =  '2'.  
                  RETURN.  
              ENDTRY.  
  
            ENDIF.  
          CATCH cx\_os\_object\_not\_found.  
            rp\_status =  '2'.  
            RETURN.  
        ENDTRY.  
  
      ENDIF.  
    ENDIF.  
  
  ENDMETHOD.

**BADI to implement custom schedule condition.**



 METHOD if\_ex\_eval\_schedcond\_ppf~evaluate\_schedule\_condition.  
\*----------------------------------------------------------------------------------------------------  
\*   This method looks for custom schedule condition ZEWM\_EI\_HU\_LABEL\_SC to print the custom HU lable  
\*   Form : ZEWM\_AF\_HU\_LABEL  
\*----------------------------------------------------------------------------------------------------  
  
    CALL FUNCTION '/SCWM/SCHEDULE\_COND\_HU'  
      EXPORTING  
        io\_context   = io\_context  
        ip\_protocol  = ip\_protocol  
        ip\_ttype     = ip\_ttype  
        flt\_val      = flt\_val  
        ii\_container = ii\_container  
      IMPORTING  
        ep\_rc        = ep\_rc.  
  
  ENDMETHOD.